2.4. Wat is de gemiddelde contractomvang personeel?

Concepten

• Arbeidsovereenkomst
• Contractomvangwaarde
• Functie in organisatie-rol
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft meeteenheid
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.4 
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX time: <http://www.w3.org/2006/time#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10
11SELECT
12	?Periode
13    (?vestiging AS ?Indeling)
14	(IF( COUNT(DISTINCT ?zorg_persoon)=0,"Ongedefineerd", ROUND( (SUM(?teller_waarde * ?zorg) / COUNT(DISTINCT ?zorg_persoon)) * 100 ) / 100 ) AS ?Gemiddeld_aantal_contracturen_zorgverleners)
15    (IF( COUNT(DISTINCT ?niet_zorg_persoon)=0,"Ongedefineerd", ROUND( (SUM(?teller_waarde * ?niet_zorg) / COUNT(DISTINCT ?niet_zorg_persoon)) * 100 ) / 100 ) AS ?Gemiddeld_aantal_contracturen_overig_personeel)
16
17{
18    #BIND(2024 AS ?jaar)
19    VALUES ?kw { 1 2 3 4 0 }  # 0 = Totaal jaar
20    BIND(xsd:integer(?jaar) AS ?_jaar)
21
22    BIND( IF(?kw=0,
23            xsd:date(CONCAT(STR(?_jaar), "-01-01")),
24            xsd:date(CONCAT(STR(?_jaar), "-",
25                            IF(?kw=1,"01-01",
26                                IF(?kw=2,"04-01",
27                                IF(?kw=3,"07-01","10-01")))))
28            ) AS ?p_start )
29
30    BIND( IF(?kw=0,
31            xsd:date(CONCAT(STR(?_jaar), "-12-31")),
32            xsd:date(CONCAT(STR(?_jaar), "-",
33                            IF(?kw=1,"03-31",
34                                IF(?kw=2,"06-30",
35                                IF(?kw=3,"09-30","12-31")))))
36            ) AS ?p_eind )
37
38    BIND( IF(?kw=0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
39
40
41    ?overeenkomst 
42        a onz-pers:ArbeidsOvereenkomst ;
43        onz-pers:heeftOpdrachtnemer ?persoon ;
44        onz-g:hasPart ?overeenkomst_afspraak .
45    ?overeenkomst_afspraak
46        a onz-pers:WerkOvereenkomstAfspraak ;
47        onz-g:isAbout ?locatie ;
48        onz-g:isAbout ?functie ;
49        onz-g:startDatum ?start_afspraak .
50    OPTIONAL {
51        ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
52    }
53    FILTER (?start_afspraak <= ?p_eind && (?eind_afspraak >= ?p_start || !BOUND(?eind_afspraak)))
54
55    # Bepaal de omvang van het contract in uren per week
56    ?overeenkomst_afspraak onz-g:hasPart/onz-g:isAbout ?contract_omvang .
57
58    ?contract_omvang
59        a onz-pers:ContractOmvangWaarde ;
60        onz-g:hasDataValue ?omvang_waarde ;
61        onz-g:hasUnitOfMeasure ?omvang_eenheid .
62    ?omvang_eenheid onz-g:hasDataValue ?omvang_correctie .
63    BIND(?omvang_waarde*?omvang_correctie AS ?teller_waarde)
64    
65	?locatie a onz-g:StationaryArtifact ;
66	           onz-g:partOf* ?vestiging_uri .
67    ?vestiging_uri a onz-org:Vestiging .
68    {  
69        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
70        	?vest_nr a onz-org:Vestigingsnummer ;
71            onz-g:hasDataValue ?vestiging .
72    } UNION {
73        	# Includeer ook de organisatie als geheel en label deze als vestiging
74        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
75        	BIND("Totaal organisatie" AS ?vestiging)
76    }
77    
78    ?functie a onz-g:OccupationalPositionRole .
79    BIND(IF (EXISTS {?functie a onz-pers:ZorgverlenerFunctie}, 1, 0) AS ?zorg)
80    BIND(IF (?zorg = 0, 1, 0) AS ?niet_zorg)
81    BIND(IF(?zorg = 1, ?persoon, ?unbound) AS ?zorg_persoon)
82    BIND(IF(?niet_zorg = 1, ?persoon, ?unbound) AS ?niet_zorg_persoon)
83
84} 
85GROUP BY ?Periode ?vestiging
86ORDER BY ?Periode